Tutorial de ADO.

Este tutorial ilustra como utilizar el modelo de programación de ADO para hacer peticiones (queries) y actualizar una fuente de datos. Primero describe los pasos necesarios para realizar esta tarea. Luego el tutorial es repetido en Microsoft Visual Basic; Microsoft Visual C++ con Extensiones Visual C++ y Microsoft Visual J++, con ADO for Windows Foundation Classes (ADO/WFC).

Este tutorial está codificado en diferentes lenguajes por dos razones:

· La documentación de ADO asume que el lector codifica en Visual Basic. Esto hace la documentación conveniente para los programadores de Visual Basic, pero menos útil para los programadores que utilizan otros lenguajes. 

· Si Usted tiene alguna duda acerca de una función de ADO en particular y conoce un poco de otros lenguajes, puede ser capaz de resolver su duda al solo ver la misma función expresada en otro lenguaje. 

Cómo se presenta el tutorial.

Este tutorial está dividido en pasos que corresponden al modelo de programación ADO. Cada paso es discutido e ilustrado con un fragmento de código de Visual Basic. Al final de este tutorial, todos los fragmentos de código son integrados en un ejemplo de Visual Basic.

El ejemplo integrado es luego repetido en otros lenguajes de programación. Cada paso en cada lenguaje de programación esta numerado. Utilice el número del paso para referirse a la discusión correspondiente en este tutorial descriptivo.

El modelo de programación ADO está enunciado más abajo. Utilícelo como un mapa al avanzar a lo largo de este tutorial.

El modelo de programación ADO con objetos.

· Haga una conexión a una fuente de datos (Connection). Opcionalmente, comience una transacción. 

· Opcionalmente, puede crear un objeto para representar un comando SQL (Command). 

· Opcionalmente, especifique columnas, tablas y valores dentro del comando SQL con parámetros variables (Parameter). 

· Ejecute el comando (Command, Connection o Recordset). 

· Si el comando regresa filas, almacene las filas en un objeto de almacenamiento (Recordset). 

· Opcionalmente, puede crear una vista del objeto de almacenamiento de forma que pueda navegar, ordenar y filtrar los datos (Recordset). 

· Edite los datos, ya sea añadiendo, eliminando o cambiando filas o columnas (Recordset). 

· Si es apropiado, actualice la fuente de datos con los cambios desde el objeto de almacenamiento (Recordset). 

· Si se utilizó una transacción, acepte o rechace los cambios hechos durante la transacción. Finalice la transacción (Connection). 

Paso 1: Abra una conexión.

Usted requiere de medios para establecer las condiciones necesarias para intercambiar datos, es decir, una conexión (connection). La fuente de datos a la que se conecte, esta especificada en una cadena de conexión, aunque los parámetros especificados en una cadena de conexión pueden diferir para cada proveedor y fuente de datos.

La manera principal en la que ADO abre una conexión es con el método Connection.Open. Alternativamente, Usted puede invocar el método abreviado, Recordset.Open, tanto para abrir una conexión como para enviar un comando sobre esa conexión en una sola operación. La siguiente es la sintaxis para cada método en Visual Basic:

connection.Open CadenaDeConexión, IDUsuario, Contraseña, OpcionesDeApertura

recordset.Open Fuente, ConexiónActiva, TipoDeCursor, TipoDeBloqueo, Opciones

El comparar estos dos métodos se hacen notables algunas características útiles de los parámetros de los métodos ADO en general.

Un parámetro de método puede ser especificado de varias maneras. Por ejemplo, Recordset.Open utiliza un parámetro ConexiónActiva, el cual podría ser una cadena de literales, una variable que representa una cadena o un objeto Connection que representa una conexión abierta.

Este tutorial utiliza la cadena de literales de conexión, "DSN=pubs;uid=sa;pwd=;". (Las fuentes de datos son indirectamente especificadas por la palabra clave "DSN=". Vea la sección de "Cadenas de conexión típicas" en "Microsoft OLE DB Provider for ODBC" para más información).

Muchos objetos tienen propiedades que pueden proporcionar un argumento si un parámetro de método es omitido. Por ejemplo, provea la información de la cadena de conexión para el método Connection.Open al establecer la propiedad CadenaDeConexión (ConnectionString) del objeto Connection, luego omita el parámetro CadenaDeConexión del método Open.

Este tutorial utiliza la siguiente declaración del objeto Connection y el método Open:

Dim cnn As New ADODB.Connection

cnn.Open "DSN=pubs;uid=sa;pwd=;"

Paso 2: Creando un comando.

Un comando es una instrucción entendida por el proveedor de datos que modificará, administrará o manipulará la fuente de datos. Los comandos son típicamente escritos en SQL, aunque no se requiere un lenguaje en particular. Un comando de petición (query) requiere que el proveedor de datos regrese un objeto Recordset que contiene filas de información.

Especifique un comando como cualquiera de los siguientes:

· Texto comando, esto es, una cadena de literales o una variable que representa la cadena. 

· Un objeto que representa al comando. En este caso, es el valor de una propiedad Comando (Command) de un objeto CommandText establecido como el texto del comando. 

Este tutorial hace peticiones de toda la información en la tabla de authors en la base de datos pubs. El objeto Command es declarado, establecido con el objeto abrir Connection y el texto de comando. El código luce como este:

Dim cmd As New ADODB.Command

Set cmd.ActiveConnection = cnn

cmd.CommandText = "SELECT * from authors"

	Comandos parametrizados.

Los comandos pueden ser parametrizados. Un comando parametrizado consiste de un texto de comando que puede ser modificado con un valor especificado por el usuario cada vez que el comando es invocado.

Un comodín ("?") indica la parte del texto de comando que será modificada. Cada comodín en el texto de comando será reemplazado con el valor del objeto Parameter correspondiente en la colección Parameters cuando el comando sea ejecutado.

Hay dos maneras de crear un objeto Parameter y agregarlo a la colección Parameters del objeto Command. La primera manera es crear un objeto Parameter, establecer sus propiedades Nombre (Name), Tipo (Type), Dirección (Direction), Tamaño (Size) y Valor (Value) individualmente, y luego agregarlo a la colección Parameters. La segunda manera es crear y establecer las propiedades del objeto Parameter con el método CreateParameters del objeto Command, y luego agregar el objeto Parameter recién creado; todo en un solo estatuto.

Finalmente, llame a los métodos Command.Execute o Recordset.Open para sustituir los parámetros por los comodines y obtener un Recordset. Cambie la propiedad Value del objeto Parameter por otro nombre. Entonces llame al método Execute o a los métodos Recordset.Close y Open de nuevo para obtener un nuevo Recordset de otro autor.

Optimice el desempeño del comando parametrizado con la propiedad Prepared. Note que el método Execute no puede especificar las propiedades CursorType o LockType del objeto recordset.

Aquí hay un breve ejemplo:

Public Sub main()

Dim cnn As New ADODB.Connection

Dim cmd As New ADODB.Command

Dim prm As ADODB.Parameter

Dim strCmd As String

strCmd = "SELECT * FROM authors WHERE au_lname = ?"

cmd.CommandText = strCmd

cmd.Parameters.Append _

    cmd.CreateParameter("last name", adVarChar, adParamInput, 40, "")

cnn.Open "dsn=pubs;uid=sa;pwd=;"

cmd.ActiveConnection = cnn

cmd.Parameters("last name") = "Ringer"

DisplayRst cmd.Execute

cmd.Parameters("last name") = "Karsen"

DisplayRst cmd.Execute

cnn.Close

End Sub

Private Sub DisplayRst(rst As ADODB.Recordset)

If rst.EOF = True Then

    Debug.Print "No recordset returned for Name = '";_

               rst.ActiveCommand.Parameters(0); "'"

End If

While rst.EOF = False

    Debug.Print "Name = '"; rst!au_fname; " "; rst!au_lname; "'"

    rst.MoveNext

Wend

End Sub


Paso 3: Ejecute el comando.

Los tres métodos que regresan un Recordset son Connection.Execute, Command.Execute y Recordset.open. Esta es su sintáxis en Visual Basic:

connection.Execute(TextoComando, RegistrosAfectados, Opciones)

command.Execute(RegistrosAfectados, Parámetros, Opciones)

recordset.Open Fuente, ConexiónActiva, TipoDeCursor, TipoDeBloqueo, Opciones

Estos métodos están optimizados para aprovechar las ventajas de sus objetos particulares.

Antes de que Usted envíe un comando debe, implícita o explícitamente, abrir una conexión. Cada método que envía un comando representa la conexión de manera diferente:

· El método Connection.Execute utiliza la conexión expresado por el objeto Connection en sí mismo. 

· El método Command.Execute utiliza el objeto Connection establecido en su propiedad ConexiónActiva (ActiveConnection). 

· El método Recordset.Open utiliza una cadena de conexión, su parámetro ConexiónActiva o el objeto Connection establecido en su propiedad ConexiónActiva. 

Otra diferencia es la manera en que el comando es especificado en los tres métodos:

· En el método Connection.Execute, el comando es texto de comando. 

· En el método Command.Execute, el comando no es visible, está especificado en la propiedad Command.CommandText. Además, el comando puede ser parametrizado. 

· En el método Recordset.Open, el comando es el argumento Fuente, el cual puede ser texto de comando o un objeto Command. (El argumento Fuente puede ser también una cadena que especifique un nombre de tabla, un procedimiento almacenado o el nombre de archivo de un Recordset persistido.) 

Cada método tiene un balance diferente entre funcionalidad y desempeño:

· El método Execute está hecho para, pero no limitado para, ejecutar comandos que no regresan datos. 

· Ambos métodos Execute regresan objetos de solo lectura y unidireccionales Recordset. 

· El método Command.Execute le permite utilizar comandos parametrizados que pueden ser reutilizados eficientemente. 

· El método Open le permite especificar el TipoDeCursor (estrategia y objeto utilizado para accesar los datos) y el TipoDeBloqueo (especifica el grado de aislamiento de otros usuarios y si el cursor debe de aceptar actualizaciones en los modos inmediato o por lotes (batch) (se discuten en mas detalle más adelante). 

Estudie estas opciones, ellas representan la mayor parte de la funcionalidad de un Recordset.

Este tutorial hará cambios al Recordset en modo por lotes; por tanto se especifica un TipoDeBloqueo del tipo adLockBatchOptimistic (bloqueo por lotes optimista). El procesamiento por lotes requiere el Servicio de Cursor, así que la propiedad LocalizaciónDeCursor (Cursorlocation) también está especificada. Dado que el objeto Command ya está establecido a una conexión abierta, el parámetro ConexiónActiva no puede ser especificado en el método Open.

El Recordset es declarado y utilizado como:

Dim rs As New ADODB.Recordset

rst.CursorLocation = adUseClient

rst.Open cmd, , adOpenStatic, adLockBatchOptimistic

Paso 4: Manipule los datos.

La mayor parte de los métodos y propiedades del objeto Recordset son dedicados a examinar, navegar y manipular los datos Recordset.

Imagine al Recordset como un arreglo de filas. La fila que Usted puede examinar y manipular en un momento dado es el la fila actual (current row) y su localización dentro del Recordset es la posición de la fila actual (current row position). Cada vez que Usted se mueve a otra fila, esa fila se convierte en la nueva fila actual.

Varios métodos explícitamente mueven o "navegan" a través del Recordset (los métodos Move). Algunos métodos (el método Find) lo hacen como un efecto colateral de su operación. Además, el ajustar ciertas propiedades (la propiedad Bookmark) puede también cambiar su posición de fila. La propiedad TipoDeCursor (CursorType) del objetos Recordset o el parámetro TipoDeCursor del método Open, determinan si Usted puede navegar hacia delante y hacia atrás a través del Recordset.

La propiedad Filter (filtro) controla los renglones a lo que Usted puede accesar (esto es, cuales renglones le son "visibles"). La propiedad Sort (ordenamiento) controla el orden en el cual Usted navega las filas del Recordset.

Usted puede crear nuevas filas con el método AddNew o eliminar filas existentes con el método Delete.

Un Recordset tiene una colección de campos (fields) que es un conjunto de objetos Field que representan cada campo o columna en una fila. Asigne u obtenga los datos de un campo con la propiedad Value del objeto Field. Puede, además, accesar campos de datos en bloques con el método GetRows. Después de que Usted ha modificado el Recordset, propage sus cambios a la fuente de datos utilizando los métodos Update.

En este tutorial, Usted:

· Establecerá la propiedad Optimize en la colección Properties del objeto Field au_lname para mejorar el desempeño del ordenamiento y filtrado. 

· Ordenará el Recordset por el apellido de cada autor. 

· Filtrará el Recordset de forma que las únicas filas sean aquellas donde el número de teléfono del autor tengan el código de área "415" y el conmutador comience con "5". 

· Cambiará los números telefónicos filtrados al mítico código de área "777." 

Utilice los métodos Move para navegar desde el principio del Recordset filtrado y ordenado hasta el final. Deténgase cuando la propiedad EOF del objeto Recordset indique que se ha alcanzado la última fila. Al irse moviendo a lo largo del Recordset, visualice el nombre y apellido del autor, el número de teléfono original y luego cambie el código de área en el campo del teléfono a "777". (Los números telefónicos en el campo de teléfono se formatearán como "aaa xxx-yyyy" donde aaa es el código de área y xxx es el conmutador.)

Al ir cambiando cada fila, ya no cumple el criterio especificado por el filtro, de modo que ya no es visible en el Recordset. Todos los renglones reaparecen cuando el filtro es borrado.

	Esquema de la tabla.

El siguiente es el esquema de la tabla authors de la base de datos pubs:

Nombre de columna

Tipo de dato (Longitud)

Anulable

au_id

ID (11)

no

au_lname

varchar(40)

no

au_fname

varchar(20)

no

Phone

char(12)

no

Address

varchar(40)

yes

City

varchar(20)

yes

State

char(2)

yes

Zip

char(5)

yes

Contract

bit

no




El código luce como este:

rst!au_lname.Properties("Optimize") = True

rst.Sort = "au_lname"

rst.Filter = "phone LIKE '415 5*'"

rst.MoveFirst

Do While Not rst.EOF

    Debug.Print "Name = "; rst!au_fname; " "; rst!au_lname;_

        ", Phone = "; rst!phone

    rst!phone = "777" & Mid(rst!phone, 4)

    rst.MoveNext

Loop

rst.Filter = adFilterNone

Paso 5: Actualice los datos.

Acaba Usted de cambiar los datos de varias filas del Recordset. ADO utiliza dos nociones básicas relacionadas con la adición, eliminación o modificación de renglones de datos.

La primera noción es que los cambios no son inmediatamente hechos al Recordset; en vez de eso, son hechos a una memoria intermedia de copia (copy buffer). Si Usted decide que no desea los cambios, entonces la modificaciones en la memoria intermedia son descartadas. Si decide mantener los cambios, entonces los cambios en la memoria intermedia son aplicados al Recordset.

La segunda noción es que los cambios pueden ser propagados a la fuente de datos tan pronto como uUsted declare completo el trabajo en una fila, (esto es, modo inmediato). O todos los cambios a un conjunto de renglones son recogidos hasta que Usted declare que el trabajo para el conjunto está completo (esto es, modo por lotes). Estos modos están gobernados por las propiedades CursorLocation y LockType.

En el modo inmediato, cada invocación del método Update propaga los cambios a la fuente de datos. En el modo por lotes, cada invocación de Update o el movimiento de la posición de fila actual guarda los cambios a la memoria intermedia, pero solo el método Updatebatch propaga los cambios a la fuente de datos. El Recordset fue abierto en modo por lotes (adLockBatchOptimistic) así que las actualizaciones serán hechas en modo por lotes.

Opcionalmente, las actualizaciones pueden ser realizadas en una transacción. Una transacción establece un ambiente donde las operaciones dentro de la transacción son todas exitosas o todos sus efectos son cancelados.

Un ejemplo común de una transacción es una aplicación bancaria, donde una operación para deducir un cantidad de una cuenta y otra operación para depositar la misma cantidad en otra cuenta, ambas deben de ser exitosas. Si una falla, entonces la otra debe de ser deshecha; de otra manera las cuentas estarán fuera de balance.

Las transacciones generalmente asignan y mantienen recursos limitados en las fuentes de datos por largos períodos de tiempo. Por esta razón, es recomendable que una transacción exista por períodos tan cortos como sea posible. (Esta es la razón por la cual este tutorial no comenzó la transacción tan pronto como la conexión fue hecha).

Hablando prácticamente, este tutorial no requiere una transacción, pero se incluye una para propósitos ilustrativos. El código para comenzar una transacción y realizar una actualización por lotes luce como este:

cnn.BeginTrans

rst.UpdateBatch

Paso 6: Concluya la actualización.

Imagine que la actualización por lotes concluye con errores. El cómo Usted resuelva estos errores depende de la naturaleza y la severidad de los errores y la lógica de su aplicación. Sin embargo, si la base de datos es compartida con otros usuarios, un error típico es que alguien más modificó el campo antes de que Usted lo hiciera. Este tipo de error es llamado un conflicto. El ADO detecta esta situación y reporta un error.

Este paso del tutorial tiene dos partes: Si no hay errores de actualización, entonces la fuente de datos refleja los cambios actualizados. La transacción se ha realizado. Realizar la transacción finaliza y termina la transacción.

El código para aceptar la actualización luce como este:

cnn.CommitTrans

Si existen errores de actualización, serán interceptados en una rutina de manejo de errores. Filtre el Recordset con la constante adFilterConflictingRecords de forma que solo los renglones en conflicto sean visibles. La estrategia de resolución de errores es meramente imprimir el nombre y apellido del autor (au_fname y au_lname), luego regresar (roll back) (esto es, deshacer) la transacción. Al regresar la transacción se descarta cualquiera actualización exitosa y finaliza la transacción.

El código para rechazar la actualización luce como este:

rst.Filter = adFilterConflictingRecords

rst.MoveFirst

Do While Not rst.EOF

    Debug.Print "Conflict: Name =  "; rst!au_fname;" "; rst!au_lname

    rst.MoveNext

Loop

cnn.RollbackTrans

Después de que concluye la actualización, los objetos Recordset y Connection son cerrados y el ejemplo termina de ejecutarse. El código luce como este:

rst.Close

cnn.Close

Este es el final del tutorial descriptivo.

Tutorial ADO (Visual Basic).

Este es el tutorial de ADO, escrito en Microsoft Visual Basic. Vea el el Tutorial de ADO para una descripción del propósito de este tutorial.

Public Sub Main()    ' Tutorial in VB

Dim cnn As New ADODB.Connection

Dim cmd As New ADODB.Command

Dim rst As New ADODB.Recordset

' Step 1 - Open a Connection

cnn.Open "DSN=pubs;uid=sa;pwd=;"

' Step 2 - Create a Command

Set cmd.ActiveConnection = cnn

cmd.CommandText = "SELECT * from authors"

' Step 3 - Execute the Command

rst.CursorLocation = adUseClient

rst.Open cmd, , adOpenStatic, adLockBatchOptimistic

' Step 4 - Manipulate the Data

rst!au_lname.Properties("Optimize") = True

rst.Sort = "au_lname"

rst.Filter = "phone LIKE '415 5*'"

rst.MoveFirst

Do While Not rst.EOF

    Debug.Print "Name = "; rst!au_fname; " "; rst!au_lname; _

        ", Phone = "; rst!phone

    rst!phone = "777" & Mid(rst!phone, 4)

    rst.MoveNext

Loop

rst.Filter = adFilterNone

' Step 5 - Update the Data

cnn.BeginTrans

On Error GoTo ConflictHandler

rst.UpdateBatch

'Step 6, part A - Conclude the Update (Accept changes)

cnn.CommitTrans

ExitTutorial:

On Error GoTo 0

rst.Close

cnn.Close

Exit Sub

'Step 6, part B - Conclude the Update (Reject changes)

ConflictHandler:

rst.Filter = adFilterConflictingRecords

rst.MoveFirst

Do While Not rst.EOF

    Debug.Print "Conflict: Name =  "; rst!au_fname; " "; rst!au_lname

    rst.MoveNext

Loop

cnn.RollbackTrans

Resume ExitTutorial

End Sub

Este es el final del tutorial Visual Basic.

